% The Computer Modern Roman family of fonts (by D. E. Knuth, 1979--1985)

if ligs>1: font_coding_scheme:="TeX text";
 spanish_shriek=oct"074"; spanish_query=oct"076"; 
else: font_coding_scheme:=if ligs>0:"TeX text without f-ligatures"
  else: "TeX typewriter text" fi;
 spanish_shriek=oct"016"; spanish_query=oct"017"; fi

mode_setup; font_setup;
%stop "changes?";
%show u,stem_corr,jut,cap_jut,fine,crisp,tiny,asc_height,cap_height,
% fig_height,x_height,bar_height,desc_depth,hair,vair,bar,slab,
% stem,curve,flare,cap_hair,cap_stem,cap_curve,o;
input romanu;	% upper case (majuscules)
input romanl;	% lower case (minuscules)
input greeku;	% upper case Greek letters
input romand;	% numerals
input romanp;	% ampersand, question marks, currency sign
input romspl;	% lowercase specials (dotless i, ligature ae, etc.)
input romspu;	% uppercase specials (AE, OE, O/)
input punct;	% punctuation symbols common to roman and italic text
input accent;	% accents common to roman and italic text
if ligs>1: input romlig; fi	% letter ligatures
if ligs>0: input comlig; fi	% ligatures common with italic text
if ligs≤1: input romsub; fi	% substitutes for ligatures

ligtable "!": "`" =: spanish_shriek;
ligtable "?": "`" =: spanish_query;
font_slant slant;
font_xheight x_height#;
if monospace: font_normal_space 9u#; % no stretching or shrinking
 font_quad 18u#;
 font_extra_space 9u#;
else: font_normal_space 6u#+2letter_fit#;
 font_normal_stretch 3u#; font_normal_shrink 2u#;
 font_quad 18u#+4letter_fit#;
 font_extra_space 2u#;
 numeric k,kk,kkk; k=-.5u#; kk=-1.5u#; kkk=-2u#; % three degrees of kerning
 ligtable "k": "v": "a" kern -u#, "w": "a" kern k,
  "o" kern k, "e" kern k, "c" kern k;
 ligtable "P": "A" kern kk,
  "y": "a" kern k, "o" kern k, "e" kern k, "." kern kk, "," kern kk;
 ligtable "F": "V": "W": "A" kern kkk,
   "o" kern kk, "e" kern kk, "a" kern kk, "u" kern kk, "r" kern kk,
  "K": "X": "O" kern k, "C" kern k, "G" kern k, "Q" kern k;
 ligtable "T": "y" kern if serifs: k else: kk fi,
  "Y": "u" kern kk, "r" kern kk,
   "o" kern kk, "e" kern kk, "a" kern kk, "A" kern kk;
 ligtable "O": "D": "A" kern k, "W" kern k, "Y" kern k, "V" kern k, "X" kern k;
 if serifs: ligtable "h": "m": "n":
   "t" kern k, "u" kern k, "b" kern k, "y" kern k, "w" kern k, "v" kern k;
  ligtable "c": "h" kern k, "k" kern k; fi
 ligtable "o": "b": "p": "e" kern -k, "o" kern -k, "c" kern -k,
   "d" kern -k, "q" kern -k, "x" kern k,
  "a": "v" kern k,
  "t": "y" kern k,
  "u": "w" kern k;
 ligtable "A": if serifs: "R": fi "t" kern k,
  "L": "T" kern kk, "O" kern k, "U" kern k, "C" kern k,
   "W" kern kkk, "Y" kern kk, "G" kern k, "V" kern kkk, "Q" kern k;
 ligtable "g": "j" kern k; % logjam
 ligtable "I": "I" kern -k; % Richard III
 % there are ligature/kern programs for "f" in the romlig file
 % and for "-", "`", and "'" in the comlig file
fi;
if known Xerox_world: font_family font_identifier;
 coding_scheme font_coding_scheme;
 font_face_byte 254-2 round designsize; fi % Dover code for CM; 154==AM
tracingstats:=10; % temporary
end.